Groovy探索之对Java语言反射的简化

                           Groovy探索之对Java语言反射的简化

 

Java语言的反射功能是我们不得不使用的功能，但事实上它的使用是相当繁琐却在功能上比较单一的一个功能。

例如，我们使用Java语言反射最多的地方是在运行时对POJO对象或者Domain对象的“set”和“get”方法的调用，因为对象属性是私有的，获取和设置对象属性的值是通过对应的“get”和“set”方法进行的。下面是一个关于“get”方法调用的例子：

    public static Object getFieldValue(Object bean,Field field)

    {

       try

       {

           String type = field.getType().getName();

           if (type.equals( "boolean" )||type.equals( "java.lang.Boolean" ))

           {

              Method m1 = bean.getClass().getmethod(StrUtil.getIsMethodName(field.getName()), null );

              return m1.invoke(bean, null );

           }

           else

           {

              Method m1 = bean.getClass().getmethod(StrUtil.getgetmethodName(field.getName()), null );

           }

       }

       catch (Exception e)

       {

           e.printstacktrace();

           if ( logger .isDebugEnabled())

           {

              logger .debug( "getFieldValue" ,e);

           }

           return null ;

       }

}

 

上面的代码首先判断 Field 的属性是否为 boolean ，如果是，则调用 isXXXX() 方法；否则调用 getXXXX() 方法。

在调用的时候，首先 Field 的 name 获取对应的“ is ”或“ get ”方法名，然后获得 Method 对象，最后调用该对象的 invoke 方法获得返回值。

整个过程相当的繁琐。

但Groovy语言中，我们设置或获取对象的属性值可以直接通过“对象名.属性名”获取，因此设置和获取对象属性的值就不直接通过“set”和“get”方法了。

上面的Java代码在Groovy程序中可以改造成下面的代码：

    def static getFieldValue(Object bean,String fieldName)

    {

       bean. "$fieldName"

}

 

不错，在前面的文章中，我曾经提出， Groovy 语言的动态性跟 Gstring 有很大的关系，现在就可以看到，动态设置或获取对象属性值是通过 Gstring 对象来完成的。

真是简单得不可思议，假如有如下一个 Domain 类：

class Man

{

    String name

    String age

    String addr

}

 

我们使用该类来进行测试：

     Man man = new Man()

     man.name = 'Mike'

     man.age = '22'

     man.addr = 'Shenzhen'

     

  println getFieldValue(man, 'age' )

 

打印结果为：

22

 

再做一个测试：

     Man man = new Man()

     man.name = 'Mike'

     man.age = '22'

     man.addr = 'Shenzhen'

     

     man.MetaClass.properties. each

     {

          println "property name: ${it.name},property value: ${man." ${it.name} "}"

 }

 

结果为：

property name: class,property value: class base.Man

property name: addr,property value: Shenzhen

property name: age,property value: 22

property name: MetaClass,property value: groovy.lang.MetaClassImpl@1749757[class base.Man]

property name: name,property value: Mike

 

可以看到， Groovy 语言中设置或获取对象属性的值，根本不需要另写一个类似“ getFieldValue ”这样的方法，直接获取就行了，简单明了。

 

除了使用Gstring设置或获取对象的属性值，在运行时获取方法的返回值也是通过Gstring完成的。请看下面的例子。

我们首先在上面的Man类中加入一个“toString”方法，如下：

class Man

{

        String name

        String age

        String addr

       

        public String toString()

        {

           "$name is $age year old,and live in $addr"

        }

}

 

下面，我们就在运行时调用“toString”方法：

     Man man = new Man()

     man.name = 'Mike'

     man.age = '22'

     man.addr = 'Shenzhen'

     

      def functionName = 'toString'

  println man. "${functionName}" ()

 

可以看到，与动态设置或获取属性值唯一不同的是在 Gstring 对象后面跟了一个“ () ”。在 Groovy 语言中， Gstring 对象后面如果没有括号，表示调用的是属性；有括号表示调用的是方法。

如果你将上面代码的后一句改为如下代码：

println man. "${functionName}()"

 

则会抛出如下的Exception：

Exception in thread "main" groovy.lang.MissingPropertyException : No such property: toString() for class: base.Man

 

在Groovy语言中，这种动态调用对象方法的方法将会在很多地方派上用场。其中就有著名的委派模式。Java语言由于其语言的特点，很少使用委派模式。而面向对象的继承却在实践中遇到了越来越多的问题。

在“使用组合代替继承”口号越来越响亮的今天，委派技术将不可避免的越来越多的使用到。下面试着举出一个例子来说明。

class Buyer

{

        def borrow4Car()

        {

           println 'borrow money for car'

        }

      

        def borrow4House()

        {

           println 'borrow money for house'

        }

}

 

class Bank

{

        def borrowMoney(type)

        {

           Buyer buyer = new Buyer()

           buyer. "borrow4${type}" ()

        }

}

 

buyer 向 bank 贷款，目的各不相同，有的是为了买车，有的是为了买房。如果 bank 要调查 buyer 贷款的目的，我们需要调用 Bank 类的“ borrowMoney ”方法，但 Bank 类本身不知道 buyer 贷款的目的，因此它需要将这个功能委派给 Buyer 类。

在 Bank 类的“ borrowMoney ”方法体内，我们可以看到先 new 了一个 Buyer 对象，然后调用该对象的方法，就完成了委派的过程。

buyer. "borrow4${type}" ()

 

可以看到，委派功能的完成，同样是借助 Gstring 的动态特性，在运行时调用对象的方法。

下面来测试上面的代码：

      Bank bank = new Bank()

     

     bank.borrowMoney( 'Car' )

 

打印结果为：

borrow money for car