ASPjmail组件发送邮件函数

我们经常会用到自动发送邮件功能，如订单系统了，留言系统了，我们不可能每时每刻盯着后台去看，如果有订单了立刻回有邮件提醒，我们就方便多了。下面看编程之家实现ASPjmail组件发送邮件函数。

ASP自动发送邮件函数

'SendEmail(发送人Email,发送者,收件人Email,邮件标题,邮件内容,smtp服务器地址,邮件服务器验证密码)

Function SendEmail(frommail,fromname,tomail,subject,content,mailserver,ServerPass)

    On Error Resume Next

    Set JMail = server.CreateObject("JMail.Message") '创建Jmail对象

    JMail.Logging = True '是否使用日志

    JMail.charset = "gb2312" '邮件编码，缺省为"US-ASCII"，最好加上，免得出现乱码

    JMail.ContentType = "text/html" '邮件的格式，text/plain为纯文本型

    JMail.From = frommail '发送邮件地址，最好写邮件服务器验证的邮箱账号

    JMail.FromName = fromname '发送者，可以随便填写

    JMail.AddRecipient tomail '要发送到的邮件地址

    JMail.Subject = subject '邮件的标题

    JMail.Priority = 3 '邮件的优先级

    JMail.Body = content '邮件的内容

    JMail.MailServerUserName = frommail '邮件服务器验证账号

    JMail.MailServerPassword = ServerPass '邮件服务器验证密码

    JMail.Send(mailserver) '通过邮件服务器smtp发送邮件

    Set JMail = nothing '关闭对象

    If Err.Number<>0 Then '错误处理

        SendEmail = False

    Else

        SendEmail = True

    End If

End Function

'发送测试..

'以下用的是QQ邮箱的SMTP服务

'你也可以用你的QQ邮箱来发..不过QQ邮箱默认是没有开启SMTP服务的

'需要自己进入QQ邮箱账户开启SMTP服务服务才能发邮件的。

'把 [email protected] 改成你的收件邮箱测试一下吧

dim Send

Send=SendEmail("[email protected]","编程之家","[email protected]","我是标题","我是内容","smtp.qq.com","www.qdxw.net")

If Send then

   response.write "发送成功"

Else

   response.write "发送失败"

End If